Access Labo #43 さまざまなエクスポート方法の比較

Accessでは、テーブルやクエリのレコードを簡単に外部のさまざまなファイル形式に出力することができます。メニューバーの操作で個々に出力することもできますし、マクロを使って自動化することもできます。さらにVBAを使えば、テーブルやクエリのレコードを１件ずつ読み込んで、フィールドごとに任意の値に加工しながら出力することも可能です。

しかし逆に言えば、さまざまな出力ファイル形式、さまざまな出力手段があるということは、その中のどのような方法がもっとも速くエクスポート処理できるのか気になるところです。そこで今回は、VBAを使っていくつかのファイル形式およびエクスポート命令を実行し、その処理時間の違いを調査してみます。

まず出力するファイル形式ですが、次の３種類を比較してみます。

Sub ExportTest()

  Dim dbs As Database
  Dim rst As Recordset
  Dim lngFileNum As Long
  Dim iintLoop As Integer

  ts_Watch "処理開始", True

  For iintLoop = 1 To 10
    'テストパターン１
    DoCmd.TransferSpreadsheet acExport, acSpreadsheetTypeExcel9, _
                               "tbl受注", "受注.XLS"
    ts_Watch "XLSエクスポート"

    'テストパターン２
    DoCmd.TransferText acExportDelim, , "tbl受注", "受注.CSV"
    ts_Watch "CSVエクスポート（DoCmd）"

    'テストパターン３
    DoCmd.TransferText acExportHTML, , "tbl受注", "受注.HTM"
    ts_Watch "HTMLエクスポート"

    'テストパターン４
    lngFileNum = FreeFile()
    Open "受注.CSV" For Output As #lngFileNum
    Set dbs = CurrentDb
    Set rst = dbs.OpenRecordset("tbl受注")
    With rst
      Do Until .EOF
        Print #lngFileNum, !受注コード & "," & !商品コード & "," & _
                            !単価 & "," & !数量 & "," & !割引
        .MoveNext
      Loop
      .Close
    End With
    Close #lngFileNum
    ts_Watch "CSVエクスポート（Print #）"

  Next iintLoop

End Sub

合計

平均

最大

最小

Excelワークシート

20.98

2.10

3.03

1.03

CSVファイル（DoCmdオブジェクト）

44.06

4.41

4.52

3.44

HTMLファイル

37.27

3.73

3.75

3.67

CSVファイル（Print #ステートメント）

12.50

1.25

1.27

1.23

Sub CSVTest2()

  Dim dbs As Database
  Dim rst As Recordset
  Dim lngFileNum As Long
  Dim strOutPut As String

  lngFileNum = FreeFile()
  Open "受注.CSV" For Output As #lngFileNum
  Set dbs = CurrentDb
  Set rst = dbs.OpenRecordset("tbl受注")
  With rst
    strOutPut = ""
    Do Until .EOF
      strOutPut = strOutPut & !受注コード & "," & !商品コード & "," & _
                              !単価 & "," & !数量 & "," & !割引 & vbCrLf
      .MoveNext
    Loop
    .Close
  End With
  Print #lngFileNum, strOutPut
  Close #lngFileNum

End Sub