Access Labo #15 リンクテーブル経由か外部MDBの直接参照か？

データベースアプリケーションを、テーブルだけで構成されるデータ用のMDBとフォームやレポート・モジュールなどだけで構成されるアプリケーション用のMDBに分割して作成するような場合、そのテーブルをフォーム・レポートのレコードソースとして扱うには外部のMDB上にあるテーブルをリンクして使うしかありません。一方、モジュールからこのテーブルを参照する場合には、リンクテーブルだけでなく、WorkSpaceオブジェクトとそのOpenDatabaseメソッドを使うことによって外部のMDB上のテーブルを直接参照することができます。直接とはいってもJETデータベースエンジンが仲介していることには変わりはありません。そこで、「内部的にはJETデータベースエンジンによるほとんど同じ処理が行われ処理時間に大差はないだろう」と推測しながらも、外部MDBのテーブルに対する２つの参照方法を比較してみたいと思います。

テスト内容としては、外部のMDBファイル上にある同じテーブルに対して、５万件のレコード追加とその全レコードの読み込み、全レコードの更新、さらに全レコードの削除を２つの方法で実行してみます。

コードとしては次のように、データベースを開く部分がCurrentDbかWorkSpaceオブジェクトのOpenDatabaseメソッドかの違いだけです。

  Dim dbs As Database
  Dim rst As Recordset
  Dim ilngLoop As Long
  Dim varTemp As Variant
  Const cRecMax As Long = 50000

  'リンクテーブルに対するテストでは次の行を実行します
  Set dbs = CurrentDb
  '外部のMDBファイルを直接参照するテストでは次の行を実行します
  Set dbs = DBEngine.Workspaces(0).OpenDatabase("TestEx.mdb")

  '以下は２つのテスト共通
  Set rst = dbs.OpenRecordset("tblTest")
  ts_Watch "テスト開始", True
  GoSub AddSub        'レコードの追加
  ts_Watch "追加"
  GoSub SelectSub     'レコードの選択
  ts_Watch "選択"
  GoSub EditSub        'レコードの更新
  ts_Watch "更新"
  GoSub DeleteSub     'レコードの削除
  ts_Watch "削除"
  rst.Close: dbs.Close

  Exit Sub

AddSub: 'レコードの追加
  With rst
    For ilngLoop = 1 To cRecMax
      .AddNew
        !Data1 = "ABCDE"
        !Data2 = 12345
      .Update
    Next ilngLoop
  End With
  Return

SelectSub: 'レコードの選択
  With rst
    .MoveFirst
    For ilngLoop = 1 To cRecMax
      varTemp = !Data1
      varTemp = !Data2
      .MoveNext
    Next ilngLoop
  End With
  Return

EditSub: 'レコードの更新
  With rst
    .MoveFirst
    For ilngLoop = 1 To cRecMax
      .Edit
        !Data1 = "FGHIJ"
        !Data2 = 98765
      .Update
      .MoveNext
    Next ilngLoop
  End With
Return

DeleteSub: 'レコードの削除
  With rst
    .MoveFirst
    For ilngLoop = 1 To cRecMax
      .Delete
      .MoveNext
    Next ilngLoop
  End With
  Return