Sub OutlookMailSend2()

  Dim olApp As Outlook.Application
  Dim olMailMessage As Outlook.MailItem
  Dim olRecipient As Outlook.Recipient
  Dim blnKnownRecipient As Boolean
  Dim strRecip As String
  Dim strSubject As String
  Dim strBody As String
  Dim varAttach As Variant

  '添付ファイル用の配列。カッコ内の２は（添付ファイルの数−１）
  '動的配列を使ってもよいでしょう
  Dim astrAttachments(2) As Variant 

  '送信先メールアドレスの設定
  strRecip = "xxxxxxx@xxxx.com"
  '件名の設定
  strSubject = "Outlookメール送信のテストです"
  'メール本文の設定
  strBody = "Outlookメール送信のテストです"
  '各添付ファイルのパスを設定（ここでは３つ添付）
  astrAttachments(0) = "C:\TEST1.TXT"
  astrAttachments(1) = "C:\TEST2.TXT"
  astrAttachments(2) = "C:\TEST3.TXT"

  'Outlookのインスタンスを作成
  Set olApp = New Outlook.Application
  'メッセージを新規作成
  Set olMailMessage = olApp.CreateItem(olMailItem)
  'メッセージの内容を設定して送信メール作成
  With olMailMessage
    Set olRecipient = .Recipients.Add(strRecip)
    blnKnownRecipient = olRecipient.Resolve
    .Subject = strSubject
    .Body = strBody
    '添付ファイルの追加
    For Each varAttach In astrAttachments
      .Attachments.Add varAttach
    Next varAttach
    If blnKnownRecipient Then
      '送信実行
      .Send
    End If
  End With
  Set olMailMessage = Nothing
  olApp.Quit
  Set olApp = Nothing

End Sub