33 コントロール系 - テキストボックスの書式プロパティ値を収集する

カレントデータベース内にあるすべてのフォームとその中のすべてのコントロールを探索し、テキストボックスコントロールであるものについて、その書式プロパティの値を収集します。
  1. 「Database」オブジェクト「Container」オブジェクトを設定し、「Documents」コレクションの中から、For Each〜Nextステートメントでひとつずつフォーム情報を取り出し、「Document」オブジェクトの変数「doc」にセットしていきます。

  2. 取り出されたひとつのフォーム情報のうち、フォーム名である「Name」プロパティの値を、ここではそれを何度か使用するため、いったん変数「strFormName」にセットします。

  3. フォーム内のオブジェクトを参照するので、そのフォームを”デザインビュー”(引数に「acDesign」を指定)で開きます。

  4. まずフォーム名をイミディエイトウィンドウに出力します。

  5. そのフォーム内に配置されているすべてのコントロールのコレクションである「Controls」の中から、For Each〜Nextステートメントでひとつずつコントロール情報を取り出し、「Control」オブジェクトの変数「ctl」にセットしていきます。

  6. 取り出されたひとつのコントロール情報のうち、そのコントロールの種類を表す「ControlType」プロパティの値を調べます。
    ※その組み込み定数については「特定の種類のコントロールだけを収集する」に記載の表を参照

  7. それが特定の値(ここでは「acTextBox/テキストボックス」)であれば、さらに「書式」プロパティである「Format」プロパティの値が設定されているかどうかをその長さで判別します。

  8. Formatプロパティが設定されていたら、そのコントロールの名前である「Name」プロパティ「Format」プロパティの値をイミディエイトウィンドウに出力します。

  9. そのフォームを閉じます。
    ここではデータ収集のみでデザイン変更はありませんので、引数に「acSaveNo」を指定することで意図的に変更を保存せずに閉じます。

Sub Sample_4_08()
'テキストボックスの書式プロパティ値を収集する

  Dim dbs As Database
  Dim ctn As Container
  Dim doc As Document
  Dim ctl As Control
  Dim strFormName As String

  Set dbs = CurrentDb
  Set ctn = dbs.Containers!Forms
  For Each doc In ctn.Documents
    strFormName = doc.Name
    DoCmd.OpenForm strFormName, acDesign
    Debug.Print "■" & strFormName
    For Each ctl In Forms(strFormName).Controls
      With ctl
        If .ControlType = acTextBox Then
          If Len(.Format) > 0 Then
            Debug.Print .Name,
            Debug.Print .Format
          End If
        End If
      End With
    Next ctl
    Debug.Print "------------------"
    DoCmd.Close acForm, strFormName, acSaveNo
  Next doc

End Sub

実行例:


| Index | Prev | Next |



Copyright © T'sWare All rights reserved