29 コントロール系 - 各フォームのコントロールの位置とサイズを収集する

カレントデータベース内にあるフォーム名の一覧とともに、それぞれのフォームに配置されているコントロールの位置（上位置／左位置）とサイズ（幅／高さ）を収集します。

※VBAで扱う位置やサイズのプロパティ値の単位はすべて「twip」です。プロパティシートではcm単位で表示されますが、「1cm = 567twip」で換算できます。

  1. 「Database」オブジェクトや「Container」オブジェクトを設定し、「Documents」コレクションの中から、For Each〜Nextステートメントでひとつずつフォーム情報を取り出し、「Document」オブジェクトの変数「doc」にセットしていきます。

  2. 取り出されたひとつのフォーム情報のうち、フォーム名である「Name」プロパティの値を、ここではそれを何度か使用するため、いったん変数「strFormName」にセットします。

  3. フォーム内のオブジェクトを参照するので、そのフォームを”デザインビュー”（引数に「acDesign」を指定）で開きます。

  4. まずフォーム名をイミディエイトウィンドウに出力します。

  5. そのフォーム内に配置されているすべてのコントロールのコレクションである「Controls」の中から、For Each〜Nextステートメントでひとつずつコントロール情報を取り出し、「Control」オブジェクトの変数「ctl」にセットしていきます。

  6. 取り出されたひとつのコントロール情報のうち、下記の５つのプロパティ値をイミディエイトウィンドウに出力します。
    • Name → 名前
    • Top → 上位置
    • Left → 左位置
    • Width → 幅
    • Height → 高さ

  7. そのフォームを閉じます。
    ここではデータ収集のみでデザイン変更はありませんので、引数に「acSaveNo」を指定することで意図的に変更を保存せずに閉じます。

Sub Sample_4_04()
'各フォームのコントロールの位置とサイズを収集する

  Dim dbs As Database
  Dim ctn As Container
  Dim doc As Document
  Dim ctl As Control
  Dim strFormName As String

  Set dbs = CurrentDb
  Set ctn = dbs.Containers!Forms
  For Each doc In ctn.Documents
    strFormName = doc.Name
    DoCmd.OpenForm strFormName, acDesign
    Debug.Print "■" & strFormName
    For Each ctl In Forms(strFormName).Controls
      With ctl
        Debug.Print .Name,
        Debug.Print .Top,
        Debug.Print .Left,
        Debug.Print .Width,
        Debug.Print .Height
      End With
    Next ctl
    Debug.Print "------------------"
    DoCmd.Close acForm, strFormName, acSaveNo
  Next doc

End Sub

実行例：
| Index | Prev | Next |
Copyright © T'sWare All rights reserved